root/CMakeLists.txt

cmake_minimum_required(VERSION 2.6)
set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules ${CMAKE_MODULE_PATH})
include(CheckIncludeFiles)
include(RelativePath)

# Project and version
project(boc-utils)
set(BOC_VERSION_MAJOR 0)
set(BOC_VERSION_MINOR 54)
set(BOC_VERSION_PATCH 3)
set(BOC_VERSION ${BOC_VERSION_MAJOR}.${BOC_VERSION_MINOR}.${BOC_VERSION_PATCH})

# Headers
check_include_files(syslog.h HAVE_SYSLOG_H)
if(HAVE_SYSLOG_H)
  add_definitions(-DHAVE_SYSLOG_H)
endif(HAVE_SYSLOG_H)

# Required
find_package(LibGcrypt REQUIRED)
find_package(Qt4 REQUIRED)

# Optional
find_library(LIBRFID_LIBRARY rfid)
find_library(SANE_LIBRARY sane)

# Configuration
if(LIBRFID_LIBRARY)
  message(STATUS "Found RFID library: ${LIBRFID_LIBRARY}")
  set(USE_RFID 1)
endif(LIBRFID_LIBRARY)
if(SANE_LIBRARY)
  message(STATUS "Found SANE library: ${SANE_LIBRARY}")
  set(USE_SANE 1)
endif(SANE_LIBRARY)
if(QT_PHONON_FOUND)
  set(USE_PHONON 1)
endif(QT_PHONON_FOUND)
if(QT_QTDBUS_FOUND)
  set(USE_DBUS 1)
endif(QT_QTDBUS_FOUND)

# Destination directories
set(BOC_RUNTIME_DIR bin CACHE STRING "BoC runtime directory.")
set(BOC_LIBRARY_DIR lib CACHE STRING "BoC library directory.")
set(BOC_DATA_DIR share/${PROJECT_NAME} CACHE STRING "BoC data directory.")

# Path definitions
set(BOC_CONFIG_PATH "/etc/boc-utils.conf")
relative_path(BOC_DATA_PATH ${BOC_RUNTIME_DIR} ${BOC_DATA_DIR})
configure_file(${CMAKE_SOURCE_DIR}/cmake/config.h.in ${CMAKE_BINARY_DIR}/src/config.h)

# Extra runtime dependencies
if(APPLE)
        set(BOC_EXTRA_PLUGINS
                ${QT_PLUGINS_DIR}/imageformats/libqgif.bundle
                ${QT_PLUGINS_DIR}/imageformats/libqjpeg.bundle)
endif(APPLE)
if(WIN32)
        set(BOC_EXTRA_RUNTIME
                ${CMAKE_FIND_ROOT_PATH}/bin/libeay32.dll
                ${CMAKE_FIND_ROOT_PATH}/bin/ssleay32.dll
                ${CMAKE_FIND_ROOT_PATH}/bin/libz.dll
                ${CMAKE_FIND_ROOT_PATH}/bin/QtDesigner4.dll)
        set(BOC_EXTRA_PLUGINS
                ${QT_PLUGINS_DIR}/imageformats/qgif4.dll
                ${QT_PLUGINS_DIR}/imageformats/qjpeg4.dll)
endif(WIN32)
install(FILES ${BOC_EXTRA_RUNTIME} DESTINATION ${BOC_RUNTIME_DIR})
install(FILES ${BOC_EXTRA_PLUGINS} DESTINATION ${PLUGIN_INSTALL_DIR}/imageformats)

# Packaging
set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "BoC Utilities")
set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/COPYING)
set(CPACK_PACKAGE_EXECUTABLES "boc-display" "BoC Display")
set(CPACK_PACKAGE_VERSION_MAJOR ${BOC_VERSION_MAJOR})
set(CPACK_PACKAGE_VERSION_MINOR ${BOC_VERSION_MINOR})
set(CPACK_PACKAGE_VERSION_PATCH ${BOC_VERSION_PATCH})
if(APPLE)
        set(CPACK_BUNDLE_NAME ${PROJECT_NAME})
        set(CPACK_BUNDLE_ICON ${CMAKE_SOURCE_DIR}/data/boc-utils.icns)
        set(CPACK_BUNDLE_IDENTIFIER eu.bolloretelecom.boc-utils)
        set(CPACK_BUNDLE_PLIST ${CMAKE_BINARY_DIR}/Bundle.plist)
        set(CPACK_BUNDLE_STARTUP_COMMAND ${CMAKE_BINARY_DIR}/Bundle.start)
endif(APPLE)
include(CPack)
configure_file(${CMAKE_SOURCE_DIR}/cmake/Bundle.start.in ${CMAKE_BINARY_DIR}/Bundle.start)
configure_file(${CMAKE_SOURCE_DIR}/cmake/Bundle.plist.in ${CMAKE_BINARY_DIR}/Bundle.plist)

add_subdirectory(data)
add_subdirectory(src)